求帮我制作容量大的空文件 要要求压缩了要很小的那种
发布网友
共2个回答
热心网友
做了一个批处理文件。打开记事本，将下列文字粘贴，保存时将文件类型选为“所有文件”，文件名为xx.bat，再双击执行
----------------------不包括这一行----------------------
@ECHO OFF
del a.tmp>nul 1>nul 2>nul
del model>nul 1>nul 2>nul
del BigFile>nul 1>nul 2>nul
del model*>nul 1>nul 2>nul
SETLOCAL enabledelayedexpansion
echo 制作者 : rogo96
echo.
echo 请稍后...
echo 正在做准备工作...
ECHO e 100 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 >>a.tmp
Echo rcx>>a.tmp
Echo 10>>a.tmp
Echo n model>>a.tmp
Echo w>>a.tmp
Echo q>>a.tmp
debug<a.tmp>nul
del a.tmp
::下行中若要以GB作单位,则把16改为26,KB则为6
for /l %%i in (1,1,16) DO (
copy model model%%i>nul 1>nul 2>nul
copy /b /y model+model%%i model>nul 1>nul 2>nul
del model%%i
)
set/p mb=请输入你要多少兆大小的空文件(MB):
echo.
echo 请稍后...
set n=1
set m=1
for /l %%i in (1,1,%mb%) do (
set/a n=!n!*2
if /i !n! geq %mb% goto next
set/a m+=1
)
:next
ren model model1>nul 1>nul 2>nul
set /p a=<nul>model
set b=1
for /l %%i in (2,1,%m%) DO (
set /a a=!b!*2
copy /b /y model!b!+model!b! model!a!>nul 1>nul 2>nul
set /a b=!b!*2
)
set /a n=n/2
for /l %%i in (%m%,-1,1) do (
if "!mb!"=="0" goto out
if /i !n! leq !mb! (
copy /b /y model+model!n! model>nul 1>nul 2>nul
set /a mb=!mb!-!n!
)
set /a n=!n!/2
)
:out
ren model BigFile
del model*>nul 1>nul 2>nul
echo.
echo OK
echo 文件名为 BigFile
echo 按任意键退出...
PAUSE>nul
exit
----------------------不包括这一行----------------------
比较简陋，见笑了。
热心网友
如果文件的内容全部都是0或者空格，那么文件压缩了会很小的，写程序做这样的文件非常简单，不知道你喜欢用什么程序设计语言，给了语言我给你写个程序。
